mirror of
https://github.com/TheLartians/ModernCppStarter.git
synced 2025-08-31 22:21:13 +02:00
8309eb7f98
From cmake itself: ``` Note We do not recommend using GLOB to collect a list of source files from your source tree. If no CMakeLists.txt file changes when a source is added or removed then the generated build system cannot know when to ask CMake to regenerate. The CONFIGURE_DEPENDS flag may not work reliably on all generators, or if a new generator is added in the future that cannot support it, projects using it will be stuck. Even if CONFIGURE_DEPENDS works reliably, there is still a cost to perform the check on every rebuild. ``` A standard template shouldn't even consider using glob.
66 lines
1.9 KiB
CMake
66 lines
1.9 KiB
CMake
cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
|
|
|
|
# ---- Project ----
|
|
|
|
# Note: update this to your new project's name and version
|
|
project(Greeter
|
|
VERSION 1.0
|
|
LANGUAGES CXX
|
|
)
|
|
|
|
# ---- Include guards ----
|
|
|
|
if(PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR)
|
|
message(FATAL_ERROR "In-source builds not allowed. Please make a new directory (called a build directory) and run CMake from there.")
|
|
endif()
|
|
|
|
# --- Import tools ----
|
|
|
|
include(cmake/tools.cmake)
|
|
|
|
# ---- Add dependencies via CPM ----
|
|
# see https://github.com/TheLartians/CPM.cmake for more info
|
|
|
|
include(cmake/CPM.cmake)
|
|
|
|
# PackageProject.cmake will be used to make our target installable
|
|
CPMAddPackage(
|
|
NAME PackageProject.cmake
|
|
GITHUB_REPOSITORY TheLartians/PackageProject.cmake
|
|
VERSION 1.0
|
|
)
|
|
|
|
# ---- Create library ----
|
|
|
|
# Note: for header-only libraries change all PUBLIC flags to INTERFACE and create an interface target:
|
|
# add_library(Greeter INTERFACE)
|
|
# set_target_properties(Greeter PROPERTIES INTERFACE_COMPILE_FEATURES cxx_std_17)
|
|
|
|
add_library(Greeter
|
|
${CMAKE_CURRENT_SOURCE_DIR}/include/greeter.h
|
|
${CMAKE_CURRENT_SOURCE_DIR}/source/greeter.cpp)
|
|
|
|
set_target_properties(Greeter PROPERTIES CXX_STANDARD 17)
|
|
|
|
# beeing a cross-platform target, we enforce enforce standards conformance on MSVC
|
|
target_compile_options(Greeter PUBLIC "$<$<BOOL:${MSVC}>:/permissive->")
|
|
|
|
# Link dependencies (if required)
|
|
# target_link_libraries(Greeter PUBLIC cxxopts)
|
|
|
|
target_include_directories(Greeter
|
|
PUBLIC
|
|
$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
|
|
$<INSTALL_INTERFACE:include/${PROJECT_NAME}-${PROJECT_VERSION}>
|
|
)
|
|
|
|
# ---- Create an installable target ----
|
|
# this allows users to install and find the library via `find_package()`.
|
|
|
|
packageProject(
|
|
NAME ${PROJECT_NAME}
|
|
VERSION ${PROJECT_VERSION}
|
|
BINARY_DIR ${PROJECT_BINARY_DIR}
|
|
INCLUDE_DIR ${PROJECT_SOURCE_DIR}/include
|
|
INCLUDE_DESTINATION include/${PROJECT_NAME}-${PROJECT_VERSION}
|
|
)
|