mirror of
https://github.com/TheLartians/ModernCppStarter.git
synced 2025-08-30 21:51:12 +02:00
a3bc933175
Fix install target Update cmake-format config file Format all cmake files. Update CPM.cmake version. Use FILE_SET HEADER to verify and install the header files. Prevent build problems caused by CPM_USE_LOCAL_PACKAGES Prevent problems with doctest if local found
69 lines
2 KiB
CMake
69 lines
2 KiB
CMake
cmake_minimum_required(VERSION 3.24...3.31)
|
|
|
|
project(GreeterTests LANGUAGES CXX)
|
|
|
|
# ---- Options ----
|
|
|
|
option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
|
|
option(TEST_INSTALLED_VERSION "Test the version found by find_package" OFF)
|
|
|
|
# --- Import tools ----
|
|
|
|
include(../cmake/tools.cmake)
|
|
|
|
# ---- Dependencies ----
|
|
|
|
include(../cmake/CPM.cmake)
|
|
|
|
CPMAddPackage("gh:doctest/doctest@2.4.11")
|
|
CPMAddPackage("gh:TheLartians/Format.cmake@1.8.3")
|
|
|
|
if(TEST_INSTALLED_VERSION)
|
|
find_package(Greeter REQUIRED)
|
|
else()
|
|
CPMAddPackage(
|
|
NAME Greeter
|
|
SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/..
|
|
FORCE ON
|
|
)
|
|
endif()
|
|
|
|
# ---- Create binary ----
|
|
|
|
file(GLOB sources CONFIGURE_DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/source/*.cpp)
|
|
add_executable(${PROJECT_NAME} ${sources})
|
|
target_link_libraries(${PROJECT_NAME} doctest::doctest Greeter::Greeter)
|
|
set_target_properties(${PROJECT_NAME} PROPERTIES CXX_STANDARD 17)
|
|
|
|
# enable compiler warnings
|
|
if(NOT TEST_INSTALLED_VERSION)
|
|
if(CMAKE_CXX_COMPILER_ID MATCHES "Clang" OR CMAKE_CXX_COMPILER_ID MATCHES "GNU")
|
|
target_compile_options(Greeter PUBLIC -Wall -Wpedantic -Wextra -Werror)
|
|
elseif(MSVC)
|
|
target_compile_options(Greeter PUBLIC /W4 /WX)
|
|
target_compile_definitions(${PROJECT_NAME} PUBLIC DOCTEST_CONFIG_USE_STD_HEADERS)
|
|
endif()
|
|
endif()
|
|
|
|
# ---- Add GreeterTests ----
|
|
|
|
enable_testing()
|
|
|
|
# Note: doctest and similar testing frameworks can automatically configure CMake tests. For other
|
|
# testing frameworks add the tests target instead: add_test(NAME ${PROJECT_NAME} COMMAND
|
|
# ${PROJECT_NAME})
|
|
|
|
# prevent problems if CPM_USE_LOCAL_PACKAGES is set:
|
|
if(EXISTS ${doctest_SOURCE_DIR}/scripts/cmake/doctest.cmake)
|
|
include(${doctest_SOURCE_DIR}/scripts/cmake/doctest.cmake)
|
|
doctest_discover_tests(${PROJECT_NAME})
|
|
else()
|
|
add_test(NAME ${PROJECT_NAME} COMMAND ${PROJECT_NAME})
|
|
endif
|
|
|
|
# ---- code coverage ----
|
|
|
|
if(ENABLE_TEST_COVERAGE)
|
|
target_compile_options(Greeter PUBLIC -O0 -g -fprofile-arcs -ftest-coverage)
|
|
target_link_options(Greeter PUBLIC -fprofile-arcs -ftest-coverage)
|
|
endif()
|