2db60f2ccb
* add build time dependency to static lib the header only fmt lib is used to show this * use add_test() and add a warning why doctest_discover_tests() is only availabe if doctest is not imported with find_packag() * cmake-format file * fix missed comment * back to version 1.0 respect most review comments * fix typo * update used CMP package versions * respect most review comments no default cxx language settings install fmt link against fmt::fmt export dependency too if not needed ... * use generic expression as recommended * Update CMakeLists.txt Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com> * changes acording review comments update to current PackageProject version 1.5.0 too * Update CMakeLists.txt Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com> * respect review comment remove NOLINT comment * back to begining needs to use doctest cmake modules ... it is not my idea! Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com>
83 lines
2.5 KiB
CMake
83 lines
2.5 KiB
CMake
cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
|
|
|
|
# ---- Project ----
|
|
|
|
# Note: update this to your new project's name and version
|
|
project(
|
|
Greeter
|
|
VERSION 1.0
|
|
LANGUAGES CXX
|
|
)
|
|
|
|
# ---- Include guards ----
|
|
|
|
if(PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR)
|
|
message(
|
|
FATAL_ERROR
|
|
"In-source builds not allowed. Please make a new directory (called a build directory) and run CMake from there."
|
|
)
|
|
endif()
|
|
|
|
# ---- Add dependencies via CPM ----
|
|
# see https://github.com/TheLartians/CPM.cmake for more info
|
|
|
|
include(cmake/CPM.cmake)
|
|
|
|
# PackageProject.cmake will be used to make our target installable
|
|
CPMAddPackage(
|
|
NAME PackageProject.cmake
|
|
GITHUB_REPOSITORY TheLartians/PackageProject.cmake
|
|
VERSION 1.5.0
|
|
)
|
|
|
|
CPMAddPackage(
|
|
NAME fmt
|
|
GIT_TAG 7.1.3
|
|
GITHUB_REPOSITORY fmtlib/fmt # to get an installable target
|
|
OPTIONS "FMT_INSTALL YES"
|
|
)
|
|
|
|
# ---- Add source files ----
|
|
|
|
# Note: globbing sources is considered bad practice as CMake's generators may not detect new files
|
|
# automatically. Keep that in mind when changing files, or explicitly mention them here.
|
|
file(GLOB_RECURSE headers CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/include/*.h")
|
|
file(GLOB_RECURSE sources CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/source/*.cpp")
|
|
|
|
# ---- Create library ----
|
|
|
|
# Note: for header-only libraries change all PUBLIC flags to INTERFACE and create an interface
|
|
# target: add_library(Greeter INTERFACE)
|
|
add_library(Greeter ${headers} ${sources})
|
|
|
|
set_target_properties(Greeter PROPERTIES CXX_STANDARD 17)
|
|
|
|
# being a cross-platform target, we enforce standards conformance on MSVC
|
|
target_compile_options(Greeter PUBLIC "$<$<COMPILE_LANG_AND_ID:CXX,MSVC>:/permissive>")
|
|
|
|
# Link dependencies
|
|
target_link_libraries(Greeter PUBLIC fmt::fmt)
|
|
|
|
target_include_directories(
|
|
Greeter PUBLIC $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
|
|
$<INSTALL_INTERFACE:include/${PROJECT_NAME}-${PROJECT_VERSION}>
|
|
)
|
|
|
|
# ---- Create an installable target ----
|
|
# this allows users to install and find the library via `find_package()`.
|
|
|
|
# the location where the project's version header will be placed should match the project's regular
|
|
# header paths
|
|
string(TOLOWER ${PROJECT_NAME}/version.h VERSION_HEADER_LOCATION)
|
|
|
|
packageProject(
|
|
NAME ${PROJECT_NAME}
|
|
VERSION ${PROJECT_VERSION}
|
|
NAMESPACE ${PROJECT_NAME}
|
|
BINARY_DIR ${PROJECT_BINARY_DIR}
|
|
INCLUDE_DIR ${PROJECT_SOURCE_DIR}/include
|
|
INCLUDE_DESTINATION include/${PROJECT_NAME}-${PROJECT_VERSION}
|
|
VERSION_HEADER "${VERSION_HEADER_LOCATION}"
|
|
COMPATIBILITY SameMajorVersion
|
|
DEPENDENCIES "fmt 7.1.3"
|
|
)
|