e0bf3f59d1
* Remove duplicate mentions of project name and replaced it with ${PROJECT_NAME} variable
Update CMakeLists.txt
* Added ${CMAKE_PROJECT_NAME}
* reverted usage of to Greeter and ran fix-format
* Update test/CMakeLists.txt
Co-authored-by: Dominic Dinser <dominic.dinser@leica-geosystems.com>
Co-authored-by: Lars Melchior <TheLartians@users.noreply.github.com>
60 lines
1.8 KiB
CMake
60 lines
1.8 KiB
CMake
cmake_minimum_required(VERSION 3.14 FATAL_ERROR)
|
|
|
|
project(GreeterTests LANGUAGES CXX)
|
|
|
|
# ---- Options ----
|
|
|
|
option(ENABLE_TEST_COVERAGE "Enable test coverage" OFF)
|
|
option(TEST_INSTALLED_VERSION "Test the version found by find_package" OFF)
|
|
|
|
# --- Import tools ----
|
|
|
|
include(../cmake/tools.cmake)
|
|
|
|
# ---- Dependencies ----
|
|
|
|
include(../cmake/CPM.cmake)
|
|
|
|
CPMAddPackage("gh:onqtam/doctest#2.4.5")
|
|
CPMAddPackage("gh:TheLartians/Format.cmake@1.7.0")
|
|
|
|
if(TEST_INSTALLED_VERSION)
|
|
find_package(Greeter REQUIRED)
|
|
else()
|
|
CPMAddPackage(NAME Greeter SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/..)
|
|
endif()
|
|
|
|
# ---- Create binary ----
|
|
|
|
file(GLOB sources CONFIGURE_DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/source/*.cpp)
|
|
add_executable(${PROJECT_NAME} ${sources})
|
|
target_link_libraries(${PROJECT_NAME} doctest::doctest Greeter::Greeter)
|
|
set_target_properties(${PROJECT_NAME} PROPERTIES CXX_STANDARD 17)
|
|
|
|
# enable compiler warnings
|
|
if(NOT TEST_INSTALLED_VERSION)
|
|
if(CMAKE_CXX_COMPILER_ID MATCHES "Clang" OR CMAKE_CXX_COMPILER_ID MATCHES "GNU")
|
|
target_compile_options(Greeter PUBLIC -Wall -Wpedantic -Wextra -Werror)
|
|
elseif(MSVC)
|
|
target_compile_options(Greeter PUBLIC /W4 /WX)
|
|
target_compile_definitions(${PROJECT_NAME} PUBLIC DOCTEST_CONFIG_USE_STD_HEADERS)
|
|
endif()
|
|
endif()
|
|
|
|
# ---- Add GreeterTests ----
|
|
|
|
enable_testing()
|
|
|
|
# Note: doctest and similar testing frameworks can automatically configure CMake tests. For other
|
|
# testing frameworks add the tests target instead: add_test(NAME ${PROJECT_NAME} COMMAND
|
|
# ${PROJECT_NAME})
|
|
|
|
include(${doctest_SOURCE_DIR}/scripts/cmake/doctest.cmake)
|
|
doctest_discover_tests(${PROJECT_NAME})
|
|
|
|
# ---- code coverage ----
|
|
|
|
if(ENABLE_TEST_COVERAGE)
|
|
target_compile_options(Greeter PUBLIC -O0 -g -fprofile-arcs -ftest-coverage)
|
|
target_link_options(Greeter PUBLIC -fprofile-arcs -ftest-coverage)
|
|
endif()
|